ncmpcpp-0.10_p20240912.ebuild - portage-overlay - personal portage ebuild repository

ncmpcpp-0.10_p20240912.ebuild (1724B)
      1 # Copyright 1999-2024 Gentoo Authors
      2 # Distributed under the terms of the GNU General Public License v2
      3 
      4 EAPI=8
      5 
      6 inherit autotools
      7 
      8 COMMIT="72d990fe250da1e583677474b3462b9e9894130b"
      9 
     10 DESCRIPTION="Featureful ncurses based MPD client inspired by ncmpc"
     11 HOMEPAGE="
     12 	https://rybczak.net/ncmpcpp/
     13 	https://github.com/ncmpcpp/ncmpcpp/
     14 "
     15 SRC_URI="https://github.com/ncmpcpp/ncmpcpp/archive/${COMMIT}.tar.gz -> ${P}.gh.tar.gz"
     16 S="${WORKDIR}/${PN}-${COMMIT}"
     17 
     18 LICENSE="GPL-2+"
     19 SLOT="0"
     20 KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
     21 IUSE="clock icu outputs taglib visualizer"
     22 
     23 RDEPEND="
     24 	>=media-libs/libmpdclient-2.1
     25 	dev-libs/boost:=[icu?,nls]
     26 	icu? ( dev-libs/icu:= )
     27 	net-misc/curl
     28 	sys-libs/ncurses:=[unicode(+)]
     29 	sys-libs/readline:=
     30 	taglib? ( media-libs/taglib )
     31 	visualizer? ( sci-libs/fftw:3.0= )
     32 "
     33 DEPEND="${RDEPEND}"
     34 BDEPEND="virtual/pkgconfig"
     35 
     36 DOCS=( CHANGELOG.md README.md )
     37 
     38 src_prepare() {
     39 	default
     40 	eautoreconf
     41 
     42 	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
     43 	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
     44 }
     45 
     46 src_configure() {
     47 	local myeconfargs=(
     48 		--without-lto # --with-lto only appends -flto. We need more for a dedicated USE flag
     49 		$(use_enable clock)
     50 		$(use_enable outputs)
     51 		$(use_enable visualizer)
     52 		$(use_with taglib)
     53 		$(use_with visualizer fftw)
     54 	)
     55 
     56 	econf "${myeconfargs[@]}"
     57 }
     58 
     59 src_install() {
     60 	default
     61 
     62 	dodoc doc/{bindings,config}
     63 }
     64 
     65 pkg_postinst() {
     66 	echo
     67 	elog "Example configuration files have been installed at"
     68 	elog "${EROOT}/usr/share/doc/${PF}"
     69 	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
     70 	elog "as user configuration files."
     71 	echo
     72 	if use visualizer; then
     73 		elog "If you want to use the visualizer, mpd needs to be built with fifo USE flag."
     74 		echo
     75 	fi
     76 }